7.2.1 アプリケーション接続環境の開設

rdbstartコマンドから呼び出されて、アプリケーション接続環境の開設を行うスクリプトまたはバッチファイルを、アプリケーション接続環境の開設プロシジャと呼びます。

Symfoware/RDB起動時に、DSIのメモリ常駐、共用バッファプールの開設と登録、定義情報のメモリ常駐化の機能を有効にするためには、アプリケーション接続環境の開設プロシジャを登録しておく必要があります。

DSIのメモリ常駐の詳細については、“7.4 DSIのメモリ常駐”、共用バッファプールの開設と登録の詳細については、“7.5 共用バッファプールの開設と登録”を、定義情報のメモリ常駐化の詳細については、“13.2.4 定義情報のメモリ常駐化”を参照してください。

7.2.1.1 登録方法

アプリケーション接続環境の開設プロシジャの登録は、サンプルプロシジャを以下のディレクトリ配下に複写し、環境にあわせて修正してください。

サンプルプロシジャ名は、Symfoware Serverのインストールディレクトリ\RDB\DEMO\RDBPROC_APLENV.BATです。

運用形態	複写先ディレクトリ名
RDBシステム名をつける運用	Symfoware Serverのインストール時に指定した制御ファイル格納先ディレクトリ\rdb\etc\RDBシステム名
RDBシステム名をつけない運用	Symfoware Serverのインストール時に指定した制御ファイル格納先ディレクトリ\rdb\etc

サンプルプロシジャを以下に示します。

set ERRLOG=C:\TEMP\RDBPROC_APLENV.errorlog
set CRBFLIST=C:\SFWETC\RDB\ETC\crbflist.txt
set CNBFLIST=C:\SFWETC\RDB\ETC\conbflist.txt
set RESILIST=C:\SFWETC\RDB\ETC\residentlist.txt
set PLDCLIST=C:\SFWETC\RDB\ETC\pldiclist.txt

rdbcrbf -f %CRBFLIST% >> %ERRLOG% 2>&1
if not %ERRORLEVEL%==0 goto ERRCRBF

rdbconbf -f %CNBFLIST%  >> %ERRLOG% 2>&1
if not %ERRORLEVEL%==0 goto ERRCNBF

rdbresident -mon -f %RESILIST% >> %ERRLOG% 2>&1
if not %ERRORLEVEL%==0 goto ERRRESI

rdbpldic -U %PLDCLIST% >> %ERRLOG% 2>&1
if not %ERRORLEVEL%==0 goto ERRPLDC

rem apcspv >> %ERRLOG% 2>&1
rem if not %ERRORLEVEL%==0 goto ERRAPCSPV

exit 0


:ERRCRBF
echo "rdbcrbf ended abnormally" >> %ERRLOG%
goto ERREXIT

:ERRCNBF
echo "rdbconbf ended abnormally" >> %ERRLOG%
rdbdrbf -f %CRBFLIST%
goto ERREXIT

:ERRRESI
echo "rdbresident ended abnormally" >> %ERRLOG%
rdbdisbf -f %CNBFLIST%
rdbdrbf -f %CRBFLIST%
goto ERREXIT

:ERRPLDC
echo "rdbpldic ended abnormally" >> %ERRLOG%
rdbresident -moff -f %RESILIST%
rdbdisbf -f %CNBFLIST%
rdbdrbf -f %CRBFLIST%
goto ERREXIT

:ERRAPCSPV
echo "apcspv ended abnormally" >> %ERRLOG%
rdbresident -moff -f %RESILIST%
rdbdisbf -f %CNBFLIST%
rdbdrbf -f %CRBFLIST%
rdbpldic -D %PLDCLIST%
goto ERREXIT

:ERREXIT
exit 1

7.2.1.2 アプリケーション接続環境の開設プロシジャ利用時の注意点

アプリケーション接続環境の開設プロシジャの利用に際して、注意すべき点を以下に示します。

起動タイミング

rdbstartコマンドまたは、Symfoware/RDBサービス起動時に実行されます。

rdbstartコマンドまたは、Symfoware/RDBサービス起動は、プロシジャの復帰を待ち合わせます。

なお、本プロシジャ実行中を含めて、Symfoware/RDBサービス起動が完了するまで、ユーザアプリケーションはデータベースへ接続できません。

プロシジャの権限

プロシジャの複写先ディレクトリにはAdministratorsグループのみにフルコントロールを指定してください。

サンプルプロシジャの複写は、“Administrator”権限のあるユーザ(Administratorsグループに属するユーザIDを持つ)が行ってください。

複写したプロシジャにはAdministratorsグループのみにフルコントロールを指定してください。

環境変数

本プロシジャに処理が遷移した場合には、以下の環境変数が有効です。

RDBNAME：: Symfoware/RDBサービスのセットアップ時のRDBシステム名（RDBシステム名をつけない運用の場合は設定されません）

実行可能な処理

以下のRDBコマンドが実行可能です。また、データベース構成の変更時に、本スクリプトを修正する必要をなくすために、ファイル指定での実行を推奨します。

rdbconbf
rdbcrbf
rdbdisbf
rdbdrbf
rdbpldic
rdbresident

Connection Managerを利用する場合は、以下のAPCコマンドを実行するようにプロシジャを編集してください。

apcspv

終了ステータス

本プロシジャが0以外の値で復帰した場合には、rdbstartコマンドが失敗して0以外の終了ステータスとなるか、またはSymfoware/RDBサービス起動が失敗します。

本プロシジャの終了ステータスは、0～255の範囲で指定してください。

標準出力および標準エラー出力

本プロシジャ内で実行したコマンドのメッセージは、rdbstartコマンドを実行した端末には出力されません。保存する場合は、プロシジャ内で適当なファイルへリダイレクトしてください。