3.3.4 追加された仮想PCを自動的にL-Serverに関連付けする手順

追加された仮想PCを自動的にL-Server関連付けする場合、管理者は以下のスクリプトと定義ファイルを作成してください。

L-Server関連付けスクリプトの格納先サーバ: 本製品の管理サーバ

L-Server関連付けスクリプトのファイル名: 半角英数字の任意の名前とし、拡張子はbatとします。

文字コード: Shift-JIS

終了ステータス

0: 正常終了

0以外: エラー終了

L-Server関連付けスクリプトの内容

L-Server関連付けスクリプトの内容を以下に示します。

@echo off

setlocal enabledelayedexpansion

set AUTO_CONVERT_PATH=%~dp0
set RUN_SCRIPT="インストールフォルダー\SVROR\Manager\bin\convertVMtoLServer"
set CSVPATH=CSV設定ファイルを格納するためのフォルダーの絶対パス
set CSVFILE=convertVMtoLserver.csv
set CSVFULLPATH=%CSVPATH%\%CSVFILE%
set CSVTEMP=%CSVPATH%\temp.csv
set UNCONVERT_VMNAMES=%AUTO_CONVERT_PATH%\unconvert_vmname.txt
set RESULTCSVFILE=%CSVPATH%\convertVMtoLserver_result.csv

echo [%DATE:/=-% %TIME%] auto convert Start
call %RUN_SCRIPT% -exportfile "%CSVPATH%" -fixfilename

if not !errorlevel!==0 (
 echo make csv file failed.
 echo [%DATE:/=-% %TIME%] auto convert End
 exit /b 1
) else (
 if exist "%UNCONVERT_VMNAMES%" (
  for %%a in ("%UNCONVERT_VMNAMES%") do (
   if not "%%~za" equ "0" (
    for /f "tokens=1 delims=" %%i in ('findstr /v /g:"%UNCONVERT_VMNAMES%" "%CSVFULLPATH%"') do (
                                                                          echo %%i>>"%CSVTEMP%")
    del "%CSVFULLPATH%"
    ren "%CSVTEMP%" "%CSVFILE%"
   )
  )
 )
 call %RUN_SCRIPT% -file "%CSVFULLPATH%"
 if not !errorlevel!==0 (
  echo display convertVMtoLserver.csv start
  for /f "tokens=*" %%a in (%RESULTCSVFILE%) do echo %%a
  echo display convertVMtoLserver.csv end
  echo convert lserver or make xml file failed.
  echo [%DATE:/=-% %TIME%] auto convert End
  exit /b 1
 )
)
echo convert lserver is successfully completed.
echo [%DATE:/=-% %TIME%] auto convert End
exit /b 0

注意

convertVMtoLServerコマンドに-fixfilenameオプションを指定して仮想PCを関連付けした場合、CSV結果ファイルは常にconvertVMtoLserver_result.csv となります。
出力先のディレクトリに、すでに同名のCSV結果ファイルが存在する場合、CSV結果ファイルを削除し、再作成します。-fileオプションを指定したconvertVMtoLServerコマンドの終了ステータスが0以外の場合、CSV結果ファイルの内容を標準出力に出力します。
CSV設定ファイルを格納するためのフォルダーの絶対パスには、半角英数字、アンダースコア("_")およびハイフン("-")以外の文字を使うことができません。

一括関連付け対象外仮想PC定義ファイルの内容

一括関連付け対象外仮想PC定義ファイルの内容を以下に示します。

リソースプール名,VMホスト名,仮想PC名を指定することで、特定の仮想PCだけを一括関連付け対象外にできます。

一括関連付け対象外仮想PC定義ファイルの書式

定義ファイルの格納場所: L-Server関連付けスクリプトと同じフォルダー

定義ファイルの名前: unconvert_vmname.txt

文字コード: Shift-JIS

改行コード: CR/LF

定義ファイルの形式

以下の形式で記述します。空白および空行を記述しないでください。

/リソースプール名/VMホスト名/一括関連付け対象外とする仮想PC名1
/リソースプール名/VMホスト名/一括関連付け対象外とする仮想PC名2

例

/VMHostPool/vmesx3/win2008
/VMHostPool/vmesx2/win2003

「3.3.4.1 L-Server関連付けスクリプトの作成」で作成したスクリプトをOSのタスクスケジューラに登録し、定期的に実施することで追加された仮想PCを自動的にL-Serverに関連付けできます。

OSのタスクスケジューラに登録してL-Server関連付けスクリプトを実行する手順を以下に示します。

「3.3.4.1 L-Server関連付けスクリプトの作成」で作成したスクリプトファイルを任意の場所にコピーします。
また、一括関連付け対象外の仮想PCがある場合は、一括関連付け対象外仮想PC定義ファイルも同じ場所にコピーします。
管理サーバに、OSの管理者でログインします。
タスクスケジューラを起動します。
起動方法を以下に示します。
- Windows Server 2008の場合
  [システムとメンテナンス]－[管理ツール]－[タスクスケジューラ]
- Windows Server 2008 R2の場合
  [システムとセキュリティ]－[管理ツール]－[タスクスケジューラ]
- Windows Server 2012またはWindows Server 2012 R2の場合
  [スタート]－[管理ツール]－[タスクスケジューラ]
- Windows Server 2016の場合
  [スタート]－[Windows 管理ツール]－[タスクスケジューラ]
タスクスケジューラに以下を設定します。
- タスク名
- タスクの開始日時
- 実行するプログラムとして、手順1.でコピーしたスクリプトファイルを設定します。

例

動作結果をD:\tmp\auto_convert.logに出力するようにした設定例
```
L-Server関連付けスクリプト >> D:\tmp\auto_convert.log 2>&1
```

動作結果の例

[2017-07-28 10:57:34.62] auto convert Start
VmGuest export Start
VmGuest export End
VmGuest Convert Start
VmGuest:/VMHostPool/vmesx2/win2003 convert failed
VmGuest Convert End
display convertVMtoLserver.csv start
VMGuestName,Label,Comment,FolderName,Result,Note
/VMHostPool/vmesx2/win2003,,,,NG,FJSVrcx:ERROR:67154:/VMHostPool/vmesx2/win2003:not found
display convertVMtoLserver.csv end
convert lserver or make xml file failed.
[2017-07-28 10:57:37.92] auto convert End

3.3.4 追加された仮想PCを自動的にL-Serverに関連付けする手順

3.3.4.1 L-Server関連付けスクリプトの作成

3.3.4.2 L-Server関連付けスクリプトの実行手順