クライアントマシンにJBKプラグインがインストールされているかどうかを、Webページで判別する方法を紹介します。
VBScriptやJavaScriptを用いることで、クライアントマシン上のJBKプラグインのバージョン番号を確認することができます。
これにより、WebブラウザでWebページを開いたときに、最新のJBKプラグインがインストールされていない場合に、 インストーラのダウンロードを促すWebページに移動するといった使い方ができます。
クライアントにJBKプラグインがインストールされているかどうかを判別するスクリプトの例を、以下に示します。
<HTML>
<HEAD>
<TITLE>JBKプラグインのインストールを確認するページ</TITLE>
<!-- Internet Explorer用スクリプト -->
<SCRIPT LANGUAGE="VBScript">
<!--
' 最新のJBKプラグインのバージョン番号
Const PLG_REQUIRED_VERSION = 9.01
' インストーラ用WebページのURL
Const PLG_INSTALL_URL = "http：//foo.fujitsu.com/index.html"
Dim CurrentVersion
CurrentVersion = 0.0
' インストールされているJBKプラグインのバージョン番号を取得する
' JBKプラグインがインストールされていない場合はGetPluginVersion()が
' エラーを返すが、"On Error Resume Next"を指定しているので、
' CurrentVersionが0.0のまま処理は続行する
On Error Resume Next
CurrentVersion = GetPluginVersion()
' 最新のJBKプラグインがインストールされていない場合
If CurrentVersion < PLG_REQUIRED_VERSION Then
' インストール手順を説明するWebページに移動するかどうかを
' ユーザに問い合わせる
Dim Msg1, Msg2
Msg1 = "最新のJBKプラグインをインストールする必要があります。"
Msg2 = "インストール手順を説明するWebページに移動しますか？"
Dim ok
ok = MsgBox (Msg1 + Chr(13) + Msg2, vbOKCancel)
' インストール手順を説明するWebページに移動する
If ok = vbOK Then
document.location = PLG_INSTALL_URL
End If
End If
'
' インストールされているJBKプラグインのバージョン番号を取得する関数
'
Function GetPluginVersion
Const PLG_NAME = "F5CXWPIE.JBKPluginCtrl.1"
Dim Plugin
Set Plugin = CreateObject(PLG_NAME)
GetPluginVersion = Plugin.version
End Function
-->
</SCRIPT>
</HEAD>
<BODY>
JBKプラグインのインストール確認
</BODY>
</HTML> |
クライアントにJBKプラグインがインストールされていない場合、あるいは、インストールされているJBKのバージョンが9.01よりも古い場合にメッセージボックスを表示して、インストーラ用のWebページに移動する、という処理を行っています。
Internet Explorer用の処理はVBScriptで記述していますが、JavaScriptで記述しても有効となります。
VBScriptやJavaScriptの詳細は、それぞれのドキュメントを参照してください。
スクリプト内で使用するJBKプラグインのバージョン番号を求め方は、以下のとおりです。
エクスプローラ上で、(JBKプラグインのインストールフォルダ)\bin\f5cxwpie.ocxをマウスで右クリックします。
メニューが表示されるので[プロパティ]を選択します。
f5cxwpie.ocxのプロパティが表示されるので、[バージョン情報]タブを選択します。
詳細項目の[製品バージョン]を選択します。
[情報]欄にVL表記が表示されます。JBKプラグインのバージョン番号はこのVL表記から以下の計算式で求められます。
(バージョン番号)＝(V)＋((L)／1000) |
※(V)はVL表記のバージョン部、(L)はVL表記のレベル部
V9.2.0の場合は、V9.2L00と置き換えてください。バージョン番号は 9.2＋(0／1000)＝9.2 となります。
V11.0の場合は、V11.0L00と置き換えてください。バージョン番号は 11.0＋(0／1000)＝11.0 となります。
同じスクリプトを複数のHTMLファイルで使用する場合は、HTMLのSCRIPT要素が便利です。
<SCRIPT LANGUAGE="VBSCript" SRC="xxx.js"> |
SCRIPT要素の詳細は、HTML関連のドキュメントを参照してください。
注意
<BODY>～</BODY>内にJBKプラグインを使用するためのタグ(<OBJECT>あるいは<EMBED>)を記述すると、 クライアントマシンにJBKプラグインがインストールされている場合に、スクリプトによるバージョン確認の結果に関わらず、JBKプラグインが起動されます。 アプレットを使用しないWebページに、スクリプトを記述するようにしてください。
