ページの先頭行へ戻る
Systemwalker Desktop Keeper V14g 導入ガイド
Systemwalker
第3章 保守 > 3.1 管理サーバ/統合管理サーバの保守 > 3.1.2 ユーザー資産を退避する
前次

3.1.2 ユーザー資産を退避する

本製品が提供するユーザー資産のバックアップ機能には以下の2つがあります。

バッグアップツール(GUI)

GUI画面によりバックアップ条件を設定して実行します。

バックアップコマンド

コマンドへのパラメーター指定によりバックアップ条件を設定します。コマンド自身にスケジュール機能はありません。

ポイント

タスクにコマンドを登録しておくと便利です

バックアップコマンドを、スケジュール機能をもったバッチファイルに組み込むことによって、指定した日時に実行することが可能です。


バックアップツール(GUI)およびバックアップコマンドは以下の操作を行うことができます。

バックアップツール(GUI)およびバックアップコマンドの動作状況は、イベントログに出力されます。

バックアップツール(GUI)およびバックアップコマンドは、付帯データを除くユーザー資産データ（管理情報、ログ情報）をバックアップするものであり、本製品のプログラムや設定情報のすべてバックアップするものではありません。すべての情報をバックアップするには別途バックアップソフトウエア等によるバックアップを定期的におこなってください。


3.1.2.1 バックアップツール(GUI)を利用する

バックアップツール(GUI)によって、ユーザー資産をバックアップする方法について説明します。

注意

バックアップツール(GUI)の使用時に考慮すべきことについて

【出力先のディスク容量について】

退避ファイルの出力先として指定するディスクは、容量に十分余裕のあるディスクを使用してください。多量のデータを処理することでディスク容量に不足が発生する場合は、退避対象として指定する日付の範囲を狭めるなどの対応を行ってください。

【データベース関連ファイルのインストール先のディスク容量について】

データベース関連ファイルのインストール先の容量に十分余裕があるか確認してください。多量のログデータをバックアップする場合、データベース関連ファイルのインストール先ドライブに十分な空き領域が必要です。必要なディスク容量については、“Systemwalker Desktop Keeper 解説書”の“動作環境”を参照してください。

【退避・復元は各サーバで行ってください】

3階層のシステム構成の場合、それぞれの管理サーバでデータベースを持っているため、退避、復元は統合管理サーバ、管理サーバ単位で実施してください。

【データの変換について】

バックアップツールでは、ログ内のデータを変換してCSVファイルに出力する場合があります。変換内容は以下の2点です。

  • TAB、CR、LF  →  半角空白置換

  • "（ダブルクォーテーション）  →  ""（二重にする）

【付帯データの扱いについて】

付帯データ（画面キャプチャデータ、原本保管データ）については、バックアップツール/バックアップコマンドによるバックアップ対象ではありません。また、ログの削除を実行しても、付帯データは削除されません。

ポイント

バックアップツール（GUI)へのログオン履歴について

バックアップツール（GUI)へのログオン履歴はイベントログ（アプリケーション）に出力されます。


事前準備

復元を前提としたデータ退避を行う場合には、以下の設定情報を控えてください。（画面のビットマップ採取やメモを取るなど）

対象

退避画面

管理コンソール

[端末動作設定]

サーバ設定ツール

[システム設定]

[ActiveDirectory連携設定] ※Active Directory連携機能利用時

[管理者通知設定]

[管理サーバ設定]

[トレース設定]

[フォルダ/CT自己版数アップ設定]

[端末動作設定]の表示方法は以下のとおりです。

  1. [管理コンソール]を起動します。

  2. [動作設定]メニューから[端末動作設定]を選択します。

    →[端末動作設定]画面が表示されます。

サーバ設定ツールの各画面の表示方法は、“2.2.5 管理サーバ/統合管理サーバの環境を設定する”を参照してください。

注意

控えた情報は大切に保管してください

上記の設定情報はバックアップツールでは退避できません。復元後、退避時と同じ設定にする場合は、復元後に端末動作設定の再設定を行う必要があるので、バックアップデータと共に控えた情報を大切に保管してください。

バックアップを実行する

バックアップツールの使用手順は以下のとおりです。

  1. Administratorsグループに所属するユーザー、またはDomain Adminsグループに所属するユーザーでWindowsにログオンします。

  2. 統合管理サーバまたは、管理サーバをインストールしたマシンの[スタート]メニューから[プログラム]-[Systemwalker Desktop Keeper]-[サーバ]-[バックアップツール]を選択します。

    →[Systemwalker Desktop Keeper バックアップツール]画面が表示されます。

  3. サーバ設定ツールで登録したログオンID(アクセス権が“バックアップ・リストア”のログオンID)、およびパスワードを入力して、[OK]ボタンをクリックします。（初期管理者のログオンID、パスワードを使用してもログオンできます）

    →[バックアップツール]画面が表示されます。

    [バックアップツール]画面のメニューバーについて説明します

    メニューバー

    機能概要

    [ファイル]

    [終了]

    バックアップツールを終了します。

    [情報]

    [テーブル件数確認]

    ログ情報が格納されているDBのテーブルにおけるレコード数を表示します。

    [サービス]

    [サービス状況確認]

    接続している管理サーバ上の“階層化サービス”、“サーバサービス”の動作状況を表示します。

    [サービス起動]

    接続している管理サーバ上の“階層化サービス”、“サーバサービス”を起動します。

    [サービス停止]

    接続している管理サーバ上の“階層化サービス”、“サーバサービス”を停止します。

    [設定]

    [抽出項目設定]

    ログビューア形式のバックアップ、ログテーブルのバックアップ、ログテーブルのレコード削除を行うときに、入力した日付をどのデータ項目で抽出・削除を行うかを指定します。

      ・クライアント発生日時で処理（標準）
      ・サーバ格納日時で処理

    [自動バックアップ設定]

    自動バックアップ設定画面を表示します。

    [バックアップツールトレース]

    [しない]

    バックアップツールのトレースを採取しません。

    [概要]

    バックアップツールのトレースを概要モードで採取します。

    [詳細]

    バックアップツールのトレースを詳細モードで採取します。

    [ヘルプ]

    [オンラインヘルプ]

    オンラインマニュアルを表示します。

    [バージョン情報]

    著作権情報およびバージョン情報を表示します。

  4. バックアップツールで「管理情報」と「ログ情報」をバックアップするには、接続している管理サーバ上の“階層化サービス”、“サーバサービス”を停止する必要があります。

    1. [サービス]メニューの[サービス停止]を選択すると、サービス停止確認の画面が表示されるので[OK]ボタンをクリックします。

    2. 操作結果の状態を表す画面が表示されます。

  5. 初回のバックアップでは、ログ情報のバックアップやログ情報の削除期間を設定する場合のデータ抽出方法を設定します。[設定]メニューの[抽出項目設定]を選択します。

    →[抽出項目設定]画面が表示されます。

    この設定はログのバックアップ、ログの削除における日時指定をログがクライアント(CT)で作成された日時で処理するのか、サーバへ格納された日時で処理するかの選択です。

    • [クライアント発生日時で処理(標準)]：
      日時指定をログがクライアント(CT)で作成された日時で処理する場合に選択します。

    • [サーバ格納日時で処理]：
      日時指定をログがサーバに格納された日時で処理する場合に選択します。

  6. ログをクライアント(CT)での発生時間で抽出する場合は「クライアント発生日時で処理(標準)」を、サーバへの格納時間で抽出する場合には「サーバ格納日時で処理」を選択し、[設定]ボタンをクリックします。

    注意

    抽出項目設定は運用後に変更しないでください

    抽出項目設定は、運用開始後に変更しないでください。運用開始後に変更してバックアップを行った場合はバックアップできないログデータが発生する場合があります。抽出項目の見直しなど、運用開始後にやむを得ず設定を変更する場合は、前データをバックアップした後に変更してください。


  7. [バックアップツール]画面において、以下のステップ1～4の情報を入力します。

    ステップ1．管理情報を一括でバックアップする

    項目名

    説明

    [管理情報を一括でバックアップする]

    管理情報をバックアップする場合はチェックします。

    [バックアップファイル格納先フォルダ]

    バックアップした管理情報を格納するフォルダを選択します。指定方法は、以下のとおりです。

    • 絶対パスでフォルダ名を入力する
      出力する管理情報格納フォルダまでのパスを絶対パスで入力します。

    • [参照]ボタンから選択する
      [フォルダの参照]画面が表示されるので、出力する管理情報を格納するフォルダを選択したあとに、[開く]ボタンをクリックします。

    指定できる絶対パスの長さは、半角で189文字まで入力できます。ただし、以下の記号はフォルダ名として使用できません。
    使用できない記号:「\」「/」「:」「*」「?」「"」「<」「>」「|」

    バックアップした管理情報は指定したフォルダのサブフォルダ名MSyyyymmdd 配下に格納されます。(yyyymmddはバックアップ処理を実行した日)

    なお、同じ日に同じフォルダへ2度以上バックアップを実行した場合はサブフォルダの末尾に(1)という名前が自動的に付与されます。

    2度目  MSyyyymmdd(1)

    3度目  MSyyyymmdd(2)

    4度目  MSyyyymmdd(3)

    (以降、同様に番号が付きます)

    ステップ2．ログビューア形式のログ情報をバックアップする

    項目名

    説明

    [ログビューア形式のログ情報をバックアップする]

    ログ情報をログビューアで参照した場合と同じ形式でバックアップする場合にチェックします。

    [バックアップ対象期間]

    バックアップする期間を4つの方法で指定します。

    • 期間指定してログデータをバックアップ

      • 年は2000～9999、月は1～12、日は1～31を入力（システム日付まで指定可）

    • 指定日以前のログデータをバックアップ

      • 年は2000～9999、月は1～12、日は1～31を入力（システム日付まで指定可）

    • 本日を含め、指定した日数以前のログデータをバックアップ

      • 0～999を入力。

      • 1と指定した場合は昨日までのログデータをバックアップします。0と指定した場合は実行時点までのログデータをバックアップします。

    • 今月を含め、指定した月数以前のログデータをバックアップ

      • 0～99を入力

      • 1と指定した場合は昨月末までのログデータをバックアップします。0と指定した場合は実行時点までのログデータをバックアップします。

    [バックアップ対象のログ種別]

    バックアップするログをチェックします。

    [バックアップファイル格納先フォルダ]

    バックアップしたログ情報を格納するフォルダを選択します。指定方法は、以下のとおりです。

    • 絶対パスでフォルダ名を入力する
      出力するログ格納フォルダまでのパスを絶対パスで入力します。

    • [参照]ボタンから選択する
      [フォルダの参照]画面が表示されるので、出力するログ情報を格納するフォルダを選択したあとに、[OK]ボタンをクリックします。

    指定できる絶対パスの長さは、半角で189文字まで入力できます。ただし、以下の記号はフォルダ名として使用できません。
    使用できない記号:「\」「/」「:」「*」「?」「"」「<」「>」「|」

    バックアップしたログ情報は指定したフォルダのサブフォルダ名LVyyyymmdd 配下に格納されます。(yyyymmddはバックアップ処理を実行した日)

    なお、同じ日に同じフォルダへ2度以上バックアップを実行した場合はサブフォルダの末尾に(1)という名前が自動的に付与されます。

    2度目  LVyyyymmdd(1)

    3度目  LVyyyymmdd(2)

    4度目  LVyyyymmdd(3)

    (以降、同様に番号が付きます)

    ステップ3．ログ情報をバックアップする

    項目名

    説明

    [ログ情報をバックアップする]

    ログ情報をバックアップする場合にチェックします。

    [バックアップ対象期間]

    バックアップする期間を4つの方法で指定します。

    • 期間指定してログデータをバックアップ

      • 年は2000～9999、月は1～12、日は1～31を入力（システム日付まで指定可）

    • 指定日以前のログデータをバックアップ

      • 年は2000～9999、月は1～12、日は1～31を入力（システム日付まで指定可）

    • 本日を含め、指定した日数以前のログデータをバックアップ

      • 0～999を入力。

      • 1と指定した場合は昨日までのログデータをバックアップします。0と指定した場合は実行時点までのログデータをバックアップします。

    • 今月を含め、指定した月数以前のログデータをバックアップ

      • 0～99を入力

      • 1と指定した場合は昨月末までのログデータをバックアップします。0と指定した場合は実行時点までのログデータをバックアップします。

    [バックアップファイル格納先フォルダ]

    バックアップしたログ情報を格納するフォルダを選択します。指定方法は、以下のとおりです。

    • 絶対パスでフォルダ名を入力する
      出力するログ格納フォルダまでのパスを絶対パスで入力します。

    • [参照]ボタンから選択する
      [フォルダの参照]画面が表示されるので、出力するログ情報を格納するフォルダを選択したあとに、[OK]ボタンをクリックします。

    指定できる絶対パスの長さは、半角で189文字まで入力できます。ただし、以下の記号はフォルダ名として使用できません。
    使用できない記号:「\」「/」「:」「*」「?」「"」「<」「>」「|」

    バックアップしたログ情報は指定したフォルダのサブフォルダ名BKyyyymmdd 配下に格納されます。(yyyymmddはバックアップ処理を実行した日)

    なお、同じ日に同じフォルダへ2度以上バックアップを実行した場合はサブフォルダの末尾に(1)という名前が自動的に付与されます。

    2度目  BKyyyymmdd(1)

    3度目  BKyyyymmdd(2)

    4度目  BKyyyymmdd(3)

    (以降、同様に番号が付きます)

    ステップ4．ログ情報を削除する

    項目名

    説明

    [ログ情報を削除する]

    ログ情報を削除する場合にチェックします。

    [削除対象期間]

    ログを削除する期間を5つの方法で指定します。

    • ステップ3．の「ログ情報をバックアップする」の対象期間と同じログデータを削除

    • 期間指定してログデータを削除

      • 年は2000～9999、月は1～12、日は1～31を入力（システム日付まで指定可）

    • 指定日以前のログデータを削除

      • 年は2000～9999、月は1～12、日は1～31を入力（システム日付まで指定可）

    • 本日を含め、指定した日数以前のログデータを削除

      • 0～999を入力

      • 1と指定した場合は昨日までのログデータを削除します。0と指定した場合は実行時点までのログデータを削除します。

    • 今月を含め、指定した月数以前のログデータを削除

      • 0～99を入力

      • 1と指定した場合は昨月末までのログデータを削除します。0と指定した場合は実行時点までのログデータを削除します。

  8. [バックアップツール]画面において、共通設定項目を入力します。

    共通設定．実行ログ出力の指定

    項目名

    説明

    [実行ログファイル]

    バックアップツールの実行結果を格納するファイルを指定します。指定方法は、以下のとおりです。

    • 絶対パスでファイル名を入力する
      出力する実行結果ファイルまでのパスを絶対パスで入力します。

    • [参照]ボタンから選択する
      [ファイルを開く]画面が表示されるので、出力する実行ファイルを格納するフォルダ選択し、ファイル名を入力したあとに、[開く]ボタンをクリックします。

    指定できる絶対パスの長さは、半角で255文字まで入力できます。ただし、以下の記号はファイル名として使用できません。
    使用できない記号:「\」「/」「:」「*」「?」「"」「<」「>」「|」

    [ファイルが存在する場合]

    実行ログファイルが[実行ログファイル]で指定した場所に存在する場合の処理を選択します。

    • 追記する
      実行ログファイルが[実行ログファイル]で指定した場所に存在した場合は、前回の実行ログの後に追記します。

    • 上書きする
      実行ログファイルが[実行ログファイル]で指定した場所に存在した場合は、前回の実行ログを上書きします。

  9. すべての条件を入力したあとに、[実行]ボタンをクリックします。

    →実行を確認する画面が表示されます。

    注意

    バックアップするログの期間と削除する期間が異なっていた場合

    バックアップツールで指定したバックアップするログの期間と削除する期間が違った場合、以下のメッセージが表示されます。処理を続行すると、バックアップしていない期間を削除してしまう可能性があるので、設定が正しいか十分に確認してください。

    [BKCI-SEL001] ログ情報のバックアップで指定した対象期間と、ログ情報の削除で指定した対象期間が異なります。
対象期間を確認してください。
処理を続行しますか？

  10. 実行する場合は[OK]ボタンをクリックしてください。[バックアップ状況]画面が表示され処理が開始されます。

  11. バックアップ処理が正常終了すると、完了画面が表示されるので、[OK]ボタンをクリックします。

  12. 実施状況に表示されている情報を確認し、[閉じる]ボタンをクリックします。

  13. 停止している管理サーバの“階層化サービス”、“サーバサービス”を起動します。サービスの起動は[サービス]メニューの[サービス起動]を選択すると、サービス起動確認の画面が表示されるので[OK]ボタンをクリックします。

  14. 操作結果の状態を表す画面が表示されるので、[OK]ボタンをクリックします。

サービス状況を確認する

バックアップツールは接続している管理サーバのSystemwalker Desktop Keeperサービスの終了が必要であるため、サービスの状況を確認する必要があります。バックアップツールで、管理サーバのSystemwalker Desktop Keeperサービスの状況を確認する方法について説明します。

  1. [サービス]メニューの[サービス状況確認]を選択します。

    [サービス状況確認]画面が表示されます。以下はサービスが開始されている場合の表示です。

  2. 確認後、[OK]ボタンをクリックします。

ログ情報のテーブルのレコード件数を確認する

バックアップツールでのログ情報のバックアップ対象テーブルのレコード件数を表示する方法について説明します。

  1. [情報]メニューの[テーブル件数確認]を選択します。

    →[テーブル件数確認]画面が表示されます。テーブルの内容については、“3.1.1.2 ユーザー資産”の“ログ情報(コマンドプロンプト操作ログ以外)”を参照してください。

  2. 対象期間を入力します。

    • 年は2000～9999の範囲で入力します。

    • 月は1～12の範囲で入力します。

    • 日は1～31の範囲で入力します。

  3. [件数確認]ボタンをクリックします
    →件数がテーブル毎に表示されます。

  4. 確認後、[閉じる]ボタンをクリックします。

バックアップツールを終了する

  1. バックアップツールを終了させるには[ファイル]メニューの[終了]を選択します。
    →[終了確認]画面が表示されます。

  2. バックアップツール画面で指定した条件を保存するかどうかを選択します。条件を保存して終了する場合は[はい]を、保存せず終了する場合は[いいえ]をクリックします。終了をキャンセルする場合は[キャンセル]をクリックします。
    なお、メニューから指定した設定値（[抽出項目設定]、[デバッグトレースの設定]）は各設定時に保存されます。


3.1.2.2 バックアップ・削除を自動化する

注意

自動バックアップ・削除にかかる時間について

自動バックアップ・削除は、管理情報のバックアップ、ログビューア形式のログ情報のバックアップ、ログ情報のバックアップ、ログ情報の削除を行います。

そのため自動バックアップ・削除には、時間がかかる場合があります。

バックアップツール(GUI)からデータのバックアップ・削除を自動化する設定方法について説明します。

本設定は、運用データベース作成時にバックアップ・削除設定を行わなかった場合に実施してください。

自動バックアップ・削除は、Windowsのタスクスケジューラに登録されます。

  1. Administratorsグループに所属するユーザー、またはDomain Adminsグループに所属するユーザーでWindowsにログオンします。

  2. 統合管理サーバまたは、管理サーバをインストールしたマシンの[スタート]メニューから[プログラム]-[Systemwalker Desktop Keeper]-[サーバ]-[バックアップツール]を選択します。

    →[Systemwalker Desktop Keeper バックアップツール]初期画面が表示されます。

  3. サーバ設定ツールで登録したログオンID(アクセス権が“バックアップ・リストア”のログオンID)、およびパスワードを入力して、[OK]ボタンをクリックします。（初期管理者のログオンID、パスワードを使用してもログオンできます）

    →[バックアップツール]画面が表示されます。

  4. [設定]メニューから[自動バックアップ設定]を選択します。

    →[自動バックアップ設定]画面が表示されます。

    対象

    退避画面

    自動バックアップ・削除

    自動バックアップ・削除を行うかを設定します。

    • 行う：自動バックアップ・削除を行います。

    • 行わない：自動バックアップ・削除を行いません。

    初期値：行わない

    自動バックアップ・削除設定

    自動バックアップ・削除の設定を行います。

      

    タスク名

    タスクスケジューラに登録されるタスク名です。

    固定値です。

    バックアップ先フォルダ

    自動バックアップでデータを保存するパスを指定します。

    スケジュールの種類

    自動バックアップ・削除を行う間隔の設定を行います。

    • 日：毎日行います

    • 週：週1回行います

    • 月：月1回行います

    初期値：日

    実行曜日

    [スケジュールの種類]で[週]を選択した場合に実行する曜日を選択します。

    月～日を選択できます。

    初期値：月

    実行日

    [スケジュールの種類]で[月]を選択した場合に実行する日を入力します。

    1～31を入力できます。

    初期値：1

    実行開始時刻

    自動バックアップ・削除を実行する時間を設定します。

    00時00分～23時59分で指定できます。

    初期値：0時0分

    保存期日

    操作ログを保存する期間を設定します。

    • 日：1～365で指定できます。手入力も可能です。

    • 週：1～52で指定できます。

    • 月：1～12で指定できます。

    [スケジュールの種類]で[日]を選択した場合は、[日]だけが選択できます。

    [スケジュールの種類]で[週]を選択した場合は、[日]と[週]が選択できます。

    [スケジュールの種類]で[月]を選択した場合は、[日]と[月]が選択できます。

    初期値：

    • 日：30

    • 週：4

    • 月：1

  5. [設定]ボタンをクリックします。

注意

[実行日]で29日以降を指定すると以下のメッセージが表示されます。

実行月によって、日が存在しない場合、自動バックアップ・削除は動作しません。毎月確実に実行させるためには、28日以前を指定してください。

注意

スケジュールの設定をOSのタスク機能で直接編集した場合について

自動バックアップ設定を行うと、OSのタスク機能に「DTK_Auto_Backup_Command」というタスク名で作成されます。このタスクを直接変更した場合は、[自動バックアップ設定]画面には反映されません。

また、タスクを直接変更した後に、[自動バックアップ設定]画面で変更を行うと[自動バックアップ設定]画面で設定した内容に変更されます。


3.1.2.3 バックアップコマンドを利用する

Systemwalker Desktop Keeperが提供するバックアップコマンドによって、データベースに蓄積されているデータを操作する方法について説明します。
バックアップコマンドには、スケジューラの機能は含んでいません。

ポイント

タスクにコマンドを登録しておくと便利です

OSに標準で提供されている「タスク」の機能を使用するか、ARCserveなどのスケジューラ機能ソフトウェアを使用することによって、バックアップ作業をスケジュールできます。なお、Windows Server® 2008の場合、管理者権限で実行する必要があるので、注意してください。

注意

バックアップコマンド使用時に考慮すべきことについて

【V14.2.0専用のコマンドです】

バックアップコマンドは、V14.2.0専用のコマンドになります。異なるバージョンで構築された環境で使用した場合の動作は保証しておりません。

【コマンド実行時のカレントディレクトリについて】

バックアップコマンドを手動で起動する場合、コマンドプロンプトのカレントディレクトリを、バックアップコマンド格納フォルダに移動してください。

[格納フォルダ]
  データベース関連ファイルのインストールフォルダ\BackupCommand
  例) C:\DTKDB\BackupCommand

【出力先のディスク容量について】

退避ファイルの出力先として指定するディスクは、容量に十分余裕のあるディスクを使用してください。多量のデータを処理することでディスク容量に不足が発生する場合は、退避対象として指定する日付の範囲を狭めるなどの対応を行ってください。

【データベース関連ファイルのインストール先のディスク容量について】

データベース関連ファイルのインストール先の容量に十分余裕があるか確認してください。多量のログデータをバックアップする場合、データベース関連ファイルのインストール先ドライブに十分な空き領域が必要です。必要なディスク容量については、“Systemwalker Desktop Keeper 解説書”の“動作環境”を参照してください。

【Windows Server® 2008の場合の実行権限について】

Windows Server® 2008の場合、バックアップコマンドを実行する場合は管理者権限が必要です。Administratorsグループに所属するユーザー、またはDomain Adminsグループに所属するユーザーでWindowsにログオン後、実行してください。

【コマンドプロンプトのコマンド拡張機能を有効にしてください】

バックアップコマンドを実行するためには、コマンドプロンプトのコマンド拡張機能が有効になっている必要があります。
なお、コマンド拡張機能は、初期設定では有効になっています。コマンドプロンプトより「echo %CMDEXTVERSION%」を実行し、その結果が2以上の場合は有効と確認できます。

【コマンドの対応日付について】

バックアップコマンドが対応している日付は、2001年1月1日より、2034年12月31日までです。これ以外の期間で使用した場合の動作は保証しません。

【データの変換について】

バックアップコマンドでは、ログ内のデータを変換してCSVファイルに出力する場合があります。変換内容は以下の2点です。

  • TAB、CR、LF  →  半角空白置換

  • "（ダブルクォーテーション）  →  ""（二重にする）

【付帯データの扱いについて】

付帯データ（画面キャプチャデータ、原本保管データ）についてはバックアップ対象ではありません。付帯データの格納先フォルダの構成は、以下のとおりです。運用に応じて個別にバックアップしてください。付帯データの格納先については、“2.2.5.9 保存先フォルダを設定する”を参照してください。なお、ログの削除コマンド（DTLDELR)を実行しても、付帯データは削除されません。

  ［構成］

      付帯データの格納先フォルダ
        +-日単位のフォルダ
            +-CT単位のフォルダ

  ［例］

【メール内容データの扱いについて】

メール内容データ（メール本文、添付ファイル）についてはバックアップ対象ではありません。メール内容データの格納先フォルダの構成は、以下のとおりです。運用に応じて個別にバックアップしてください。メール内容データの格納先については、“2.2.5.9 保存先フォルダを設定する”を参照してください。

なお、ログの削除コマンド（DTLDELR)を実行しても、メール内容データは削除されません。
削除する場合は、DTKMLDL.BAT(メール内容削除)コマンドを使用してください。使用方法の詳細は、“Systemwalker Desktop Keeper リファレンスマニュアル”の“DTKMLDL.BAT(メール内容削除)”を参照してください。

  ［構成］

      メール内容データの格納先フォルダ
        +-日単位のフォルダ
            +-CT単位のフォルダ

  ［例］



バックアップコマンドの種類

Systemwalker Desktop Keeperが提供するバックアップコマンドは、10種類あります。各コマンドによって、データベースに蓄積されているデータに対して行える操作が異なります。以下にコマンドの種類と行えることについて示します。なお、バックアップコマンドは以下のフォルダに格納されています。

バックアップコマンド格納先:

[データベース関連ファイルインストール先]\BackupCommand
例) C:\DTKDB\BackupCommand

No.

コマンド名

行える操作

1

DTKMSTB.EXE

“3.1.1.2 ユーザー資産”の“各管理情報”に記述されているすべてのテーブル内のデータを、テーブルごとにCSVファイルとして退避することができます。

2

DTKLGTB.EXE

“3.1.1.2 ユーザー資産”の“ログ情報(コマンドプロンプト操作ログ以外)”に記述されているすべてのテーブル内のデータを、テーブルごとにCSVファイルとして退避することができます。

3

DTKLG1T.EXE

データベースに蓄積されているログの情報を、指定した1種別だけログビューア形式でCSVファイルに出力し、参照することができます。

4

DTKLGAT.BAT

データベースに蓄積されているログの情報を一括してログビューア形式でCSVファイルに出力し、参照することができます。

5

DTKDELR.EXE

“3.1.1.2 ユーザー資産”の“ログ情報(コマンドプロンプト操作ログ以外)”に記述されているすべてのテーブル内のデータを、データベースから削除することができます。

6

DTKBKDL.BAT

“3.1.1.2 ユーザー資産”の“ログ情報(コマンドプロンプト操作ログ以外)”に記述されているすべてのテーブル内のデータを、テーブルごとにCSVファイルとして退避して、退避したテーブル内のデータをデータベースから削除することができます。

7

DTKCVDL.BAT

“3.1.1.2 ユーザー資産”の“ログ情報(コマンドプロンプト操作ログ以外)”に記述されているすべてのテーブル内のデータを、テーブルごとにCSVファイルとして退避、およびデータベースに蓄積されているログの情報を一括してCSVファイルに出力することができます。そして、退避したテーブル内のデータをデータベースから削除することができます。

8

DTKBFDM.EXE

他のバックアップコマンドの内部で使用されているコマンドです。

過去の日付の計算を行います。

9

DTKELSET.BAT

他のバックアップコマンドの内部で使用されているコマンドです。

[ERRORLEVEL]値の再設定を行います。

10

DTKNUMCK.BAT

他のバックアップコマンドの内部で使用されているコマンドです。

バックアップコマンドのパラメーターとして入力された情報が数値かどうかのチェックを行います。

各コマンドの詳細については、“Systemwalker Desktop Keeper リファレンスマニュアル”の“コマンドリファレンス”を参照してください。


バックアップコマンドを編集する

以下のバックアップコマンドについては、使用する前に編集する必要があります。使用する環境に応じて、編集を行ってください。

なお、実行結果はイベントログのアプリケーションログに出力されます。

DTKLGAT.BAT

「DTKLGAT.BAT」を使用する場合、「DTKLGAT.BAT」をテキストエディタで開いて、以下の太字で下線を引いている箇所を編集してください。

rem *********************************************************
rem * 動作パラメーター指定ブロック                          *
rem *********************************************************

rem データベース名を記述
set SQLDB=DTKDB

rem データベースへの接続ユーザーIDを記述
set SQLuser=(*1)

rem データベースへの接続ユーザーIDに対応したパスワードを記述
set SQLpsw=(*2)

set startday=%1
set endday=%2

rem 出力ファイルの出力先のドライブ名を記述
set bkdrive=(*3)

rem 出力ファイルの出力先のフォルダ名(途中まで)を記述
set bkdir=(*4)

rem 上記のbkdirフォルダの下に作成するフォルダ名を記述
set csvdir=(*5)

rem 抽出キー(省略時はクライアント日時、「SERVER」指定時はサーバ日時)
set how=(*6) 
rem set how=SERVER

rem *********************************************************
rem * 終了処理ブロック                                      *
rem *********************************************************

:allend0
call DTKEVENT.EXE NORMALEND 1181
pause(*7)
EXIT /B 0

:allend1
call DTKEVENT.EXE ERROREND 1182
pause(*7)
EXIT /B 1

番号

編集内容

設定例

(*1)

サーバ設定ツールで登録したログオンID（アクセス権が“バックアップ・リストア”のログオンID）を入力します。

BKUSER

(*2)

上記ログオンIDのパスワードを入力します。

BKPSW

(*3)

ファイルを出力するドライブ名を入力します。(指定値の後に「:」が必要)

C:

(*4)

ファイルを出力する途中までのフォルダ名を入力します。(指定値の前に「\」が必要)

\DTKBKUP

(*5)

(*4)の配下に作成される、ファイルを出力するフォルダ名を入力します。

%2と記述するとバックアップ期間における終了日のフォルダ(例:バックアップ終了日が2007年4月20日の場合は「20070420」)が作成されます。

LV%2

(*6)

ログの退避/削除対象期間における抽出処理でログのクライアント日時(CTでのログ発生日時)かサーバ日時(サーバ格納日時)かを指定

  • 指定しない
    クライアント日時(CTでのログ発生日時)とする場合

  • SERVER
    サーバ日時(サーバ格納日時)とする場合

SERVER

(*7)

「pause」または「rem pause」を入力します。

  • 「pause」を入力した場合
    コマンド実行の終了時に一時停止させることができます。停止された状態は、コマンドプロンプトの画面で何かキーを押すと解除されます。

  • 「rem pause」を入力した場合
    コマンド実行の終了時に一時停止させません。

rem pause


DTKBKDL.BAT

「DTKBKDL.BAT」を使用する場合、「DTKBKDL.BAT」をテキストエディタで開いて、以下の太字で下線を引いている箇所を編集してください。

rem *********************************************************
rem * 動作パラメーター指定ブロック                          *
rem *********************************************************

rem データベース名を記述
set SQLDB=DTKDB

rem データベースへの接続ユーザーIDを記述
set SQLuser=(*1)

rem データベースへの接続ユーザーIDに対応したパスワードを記述
set SQLpsw=(*2)

rem 出力ファイルの出力先のドライブ名を記述
set bkdrive=(*3)

rem 出力ファイルの出力先のフォルダ名(途中まで)を記述
set bkdir=(*4)

rem 上記のbkdirフォルダの下に作成するフォルダ名を記述
set logdir=(*5)

rem 抽出キー(省略時はクライアント日時、「SERVER」指定時はサーバ日時)
set how=(*6) 
rem set how=SERVER

rem *********************************************************
rem * 終了処理ブロック                                      *
rem *********************************************************

:allend0
call DTKEVENT.EXE NORMALEND 1186
pause(*7)
EXIT /B 0

:allend1
call DTKEVENT.EXE ERROREND 1187
pause(*7)
EXIT /B 1

番号

編集内容

設定例

(*1)

サーバ設定ツールで登録したログオンID（アクセス権が“バックアップ・リストア”のログオンID）を入力します。

BKUSER

(*2)

上記ログオンIDのパスワードを入力します

BKPSW

(*3)

ファイルを出力するドライブ名を入力します(指定値の後に「:」が必要)

C:

(*4)

ファイルを出力する途中までのフォルダ名を入力します(指定値の前に「\」が必要)

\DTKBKUP

(*5)

(*5)の配下に作成される、ファイルを出力するフォルダ名を入力します。

%2と記述するとバックアップ期間における終了日のフォルダ(例:バックアップ終了日が2007年4月20日の場合は「20070420」)が作成されます。

BK%2

(*6)

ログの退避/削除対象期間における抽出処理でログのクライアント日時(CTでのログ発生日時)かサーバ日時(サーバ格納日時)かを指定

  • 指定しない
    クライアント日時(CTでのログ発生日時)とする場合

  • SERVER
    サーバ日時(サーバ格納日時)とする場合

SERVER

(*7)

「pause」または「rem pause」を入力します。

  • 「pause」を入力した場合
    コマンド実行の終了時に一時停止させることができます。停止された状態は、コマンドプロンプトの画面で何かキーを押すと解除されます。

  • 「rem pause」を入力した場合
    コマンド実行の終了時に一時停止させません。

rem pause


DTKCVDL.BAT

「DTKCVDL.BAT」を使用する場合、「DTKCVDL.BAT」をテキストエディタで開いて、以下の太字で下線を引いている箇所を編集してください。

rem *********************************************************
rem * 動作パラメーター指定ブロック                          *
rem *********************************************************

rem データベース名を記述
set SQLDB=DTKDB

rem データベースへの接続ユーザーIDを記述
set SQLuser=(*1)

rem データベースへの接続ユーザーIDに対応したパスワードを記述
set SQLpsw=(*2)

rem 処理終了日を設定するための、計測日数を記述

rem 例1. 90日前を指定する場合
set bkdays=(*3)
set bkMonth=(*3)
set bkdate=(*3)

rem例2. 3ヶ月前の月末日を指定する場合
rem set bkdays=3
rem set bkMonth=MONTH
rem set bkdate=99


rem 処理開始日を記述(ここではレコードの先頭より処理を行う設定)
set startday=(*4)

DTKBFDM.EXE %bkdays% %bkMonth% %bkdate%
if errorlevel 20350101 goto errend4
if errorlevel 20010101 goto next1
goto errend4

:next1
set endday=%errorlevel%

rem 出力ファイルの出力先のドライブ名を記述
set bkdrive=(*5)

rem 出力ファイルの出力先のフォルダ名(途中まで)を記述
set bkdir=(*6)

rem 上記のbkdirフォルダの下に作成するフォルダ名を記述(BKはバックアップ形式)
set logdir=(*7)

rem 上記のbkdirフォルダの下に作成するフォルダ名を記述(LVはログビューア形式)
set csvdir=(*8)

rem 抽出キー(省略時はクライアント日時、SERVERはサーバ日時)
set how=(*9) 
rem set how=SERVER

rem *********************************************************
rem * 終了処理ブロック                                      *
rem *********************************************************

:allend0
call DTKEVENT.EXE NORMALEND 1191
pause(*10)
EXIT /B 0

:allend1
call DTKEVENT.EXE ERROREND 1192
pause(*10)
EXIT /B 1

番号

編集内容

設定例

(*1)

サーバ設定ツールで登録したログオンID（アクセス権が“バックアップ・リストア”のログオンID）を入力します。

BKUSER

(*2)

上記ログオンIDのパスワードを入力します

BKPSW

(*3)

データを退避および削除の終了日を、「DTKCVDL.BAT」が実行される日から何日前か、または何ヶ月前で入力します。入力する値については、後述する“退避/削除対象期間”を参考にしてください。

  • set bkdays=
    日数または月数を入力します。
    日数の場合「0」～「2000」、月数の場合「0」～「120」の数字です。入力された数字が日数および月数のどちらとして判定するかは、<bkmonth>の指定により決定されます。

  • set bkMonth=
    月数を入力する場合は”MONTH”を入力します。日数で入力する場合は何も入力しません。
    "MONTH"を入力した場合は、bkdaysに月数を設定してください。

  • set bkdate=
    月数を入力した場合に「1」～「31」または「99」の数字を入力します。「1」～「31」の場合は、設定された月のその日を、「99」の場合は、設定された月の月末日が計算されます。日数で入力する場合は何も入力しません。

（90日前を指定する場合）

set bkdays=90

set bkMonth=

set bkdate=

（3ヶ月前の１日を指定する場合）

set bkdays=3

set bkMonth=MONTH

set bkdate=1

（3ヶ月前の月末日を指定する場合）

set bkdays=3

set bkMonth=MONTH

set bkdate=99

（90日前を指定する場合）

set bkdays=90
set bkMonth=
set bkdate=

（3ヶ月前の１日を指定する場合）

set bkdays=3
set bkMonth=MONTH
set bkdate=1

（3ヶ月前の月末日を指定する場合）

set bkdays=3
set bkMonth=MONTH
set bkdate=99

(*4)

データの退避および削除の開始日を入力します。入力した開始日から(*4)で入力した終了日までのデータが退避および削除の対象になります。

値の範囲は、「20010000」～「20349999」、および「00000000」です。ただし、(*3)により決定される終了日より、未来の日付を入力すると、エラーになります。

「20010000」～「20349999」の下4桁について、西暦にない値を入力した場合は、以下の日付を指定したことになります。

  • 下4桁に「0000」を指定した場合
    指定した年の1月1日が開始日となります。

  • 下4桁に「1232」～「9999」を指定した場合
    指定した年の翌年の1月1日が開始日となります。

  • 下2桁に「00」を指定した場合
    指定した月の1日が開始日となります。

  • 下2桁に「月末日の翌日」～「99」を指定した場合
    指定した月の翌月の1日が開始日となります。

なお、「00000000」を入力すると、データベースにデータが蓄積され始めたときからを指定したことになります。

入力する値については、後述する“退避/削除対象期間”を参考にしてください。

00000000

(*5)

ファイルを出力するドライブ名を入力します(指定値の後に「:」が必要)

c:

(*6)

ファイルを出力する途中までのフォルダ名を入力します(指定値の前に「\」が必要)

\DTKBKUP

(*7)

(*7)の配下に作成される、ファイルを出力するフォルダ名を入力します。

%endday%と記述するとバックアップ期間における終了日のフォルダ(例:バックアップ終了日が2007年4月20日の場合は「20070420」)が作成されます。

BK%endday%

(*8)

(*7)の配下に作成される、ファイルを出力するフォルダ名を入力します。

%endday%と記述するとバックアップ期間における終了日のフォルダ(例:バックアップ終了日が2007年4月20日の場合は「20070420」)が作成されます。

LV%endday%

(*9)

ログの退避/削除対象期間における抽出処理でログのクライアント日時(CTでのログ発生日時)かサーバ日時(サーバ格納日時)かを指定

  • 指定しない
    クライアント日時(CTでのログ発生日時)とする場合

  • SERVER
    サーバ日時(サーバ格納日時)とする場合

SERVER

(*10)

「pause」または「rem pause」を入力します。

  • 「pause」を入力した場合
    コマンド実行の終了時に一時停止させることができます。停止された状態は、コマンドプロンプトの画面で何かキーを押すと解除されます。

  • 「rem pause」を入力した場合
    コマンド実行の終了時に一時停止させません。

rem pause


退避/削除対象期間

「DTKCVDL.BAT」を使用する場合に、退避/削除対象となる期間を指定する必要があります。対象となる期間の指定に関係する、上記表の(*3)と(*4)について、以下に図示します。編集内容については、上記表の説明を参照してください。


事前準備

復元を前提としたデータ退避を行う場合には、以下の設定情報を控えてください。（画面のビットマップ採取やメモを取るなど）

対象

退避画面

管理コンソール

[端末動作設定]

サーバ設定ツール

[システム設定]

[ActiveDirectory連携設定] ※Active Directory連携機能利用時

[管理者通知設定]

[管理サーバ設定]

[フォルダ/CT自己版数アップ設定]

[端末動作設定]の表示方法は以下のとおりです。

  1. [管理コンソール]を起動します。

  2. [動作設定]メニューから[端末動作設定]を選択します。

    →[端末動作設定]画面が表示されます。

サーバ設定ツールの各画面の表示方法は、、“2.2.5 管理サーバ/統合管理サーバの環境を設定する”を参照してください。

注意

控えた情報は大切に保管してください

上記の設定情報はバックアップツールでは退避できません。復元後、退避時と同じ設定にする場合は、復元後に端末動作設定の再設定を行う必要があるので、バックアップデータと共に控えた情報を大切に保管してください。


バックアップを実行する

バックアップコマンドの使用方法については、“Systemwalker Desktop Keeper リファレンスマニュアル”の“コマンドリファレンス”を参照してください。

注意

実行時には必ずサービス停止をおこなってください

退避・復元を行う前には、サーバサービスおよび階層化サービスを停止する必要があります。停止しなかった場合、退避・復元時にデータの不整合が発生する可能性があります。

バッチファイルを作成してバックアップコマンドを実行する場合は、後述する“スケジュール登録するバッチファイルの作成例”のように、必ずサーバサービスおよび階層化サービスの停止処理を記述してください。

手作業で実施する場合の停止手順は以下のとおりです。

  1. PCに、ローカルコンピュータのAdministratorsグループに所属するユーザーまたは、ドメインのDomain Adminsグループに所属するユーザーでログオンします。
    他のアプリケーションを使用している場合は、終了してください。

  2. Windowsのサービス画面を表示し、以下の各サービスを選択して、[操作]メニューから[停止]を選択します。なお、停止するまでに30秒から1分程度かかる場合があります。

    • SWLevelControlService

    • SWServerService


以下に、バックアップコマンドを使用して、ログ運用の主な事例としてスケジュールを登録してバックアップコマンドを実行する例を２パターン説明します。

事例－I：91日以前のログを退避・削除する場合（ログ保存期間：3カ月）

運用条件

  • 運用として、データの保存期間を90日とし、それ以前のデータはデータベース上に残さず、ファイルへデータをバックアップします。

  • 毎日、91日以前のデータを、指定したドライブにバックアップ日の日付が付いたディレクトリ名を作成し、その下にデータをバックアップした出力ファイルを置きます。

  • バックアップ対象は、以下のとおりです。

    • 管理情報に記述されているすべてのテーブル(DTKMSTBを利用)

    • ログ情報（DB上のログデータおよびコマンドプロンプト操作ログ) に記述されているすべてのテーブル、およびデータベースに蓄積されているログの情報(DTKCVDLを利用)

    退避可能な情報の詳細については、“3.1.1.2 ユーザー資産”を参照してください。

  • バックアップしたデータ部分はデータベースより削除します。(DTKCVDLにより実施)

  • バックアップの実行は、OS標準実装の「タスク」機能を使用し自動起動します。ただし、データベースのレコード削除も行うため、Systemwalker Desktop Keeperのサーバ側の処理との間でデータベースアクセスの競合を発生させないように、Systemwalker Desktop Keeperのサーバ側サービスを停止してから行います。

  • サーバ側サービスを停止させることから、利用者の少ない夜間の2時より起動することとします。

  • バックアップおよびデータベースのレコード削除にかかる時間は事前に検証を行い、合わせて30分程度で終了する想定としています。


運用設定

上記の“運用条件”で説明した運用を行うために、提供するバックアップコマンドの中から、DTKMSTBとDTKCVDLの2つを使用します。

なお、本運用設定により、バックアップ先のドライブおよびフォルダの構成は、以下のようになります。(XXXXXXXXは終了日になります)

  • 管理情報に記述されているすべてのテーブル

    →D:\BACKUP\XXXXXXXX\MSXXXXXXXX\ 配下

  • ログ情報（DB上のログデータおよびコマンドプロンプト操作ログ)に記述されているすべてのテーブル

    →D:\BACKUP\XXXXXXXX\BKXXXXXXXX\ 配下

  • データベースに蓄積されているログの情報

    →D:\BACKUP\XXXXXXXX\LVXXXXXXXX\ 配下

退避可能な情報の詳細については、“3.1.1.2 ユーザー資産”を参照してください。

運用設定の手順は、以下のとおりです。

  1. DTKCVDLの内容だけを、以下のように書き換えます。

    set  SQLuser=bkuser            ・・・データベースへの接続ユーザーIDを設定
set  SQLpsw=bkpsw              ・・・接続ユーザーIDに対応したパスワードを設定
set  bkdays=90                 ・・・データの保存期間を設定
set  bkdrive=D:                ・・・ログの保存先ドライブを設定
set  bkdir=\BACKUP\%endday%    ・・・ログの保存先ディレクトリを設定
pause は rem pause へ変更

  2. 「タスク」より起動するバッチファイルをテキストエディタで作成します。
    なお、バッチファイルは、後述する“スケジュール登録するバッチファイルの作成例”のように記述します。

  3. 作成したバッチファイルを「C:\DTK\BackupCommand」に「DailySch.bat」として保存します。

  4. 運用設定で決定したログ保存先フォルダを作成します。
    運用例では、D:\BACKUPです。

  5. 「タスク」に「XXXXX.bat」のコマンドを登録します。

    1. [スタート]-[設定]-[コントロールパネル]-[タスク]と開き、スケジュールされたタスクの追加をダブルクリックします。

    2. タスクウィザードで、実行するプログラムの選択画面にて、[参照]ボタンを押下して「C:\DTK\BackupCommand\XXXXX.bat」を登録します。

    3. 名前を付け、日単位の実行として、毎日2:00に実行として登録します。

    4. 実行時のユーザーIDとパスワードを登録するので、Administrator権限のあるユーザーで登録します。


バッチファイルの作成例

運用バッチとタスクに登録する登録バッチの作成例を以下に示します。

なお、このバッチコマンド作成例では、バッチ内で呼び出したNetコマンドの復帰値をバッチコマンドの復帰値とはしないようになっています。Netコマンドの復帰値を利用して、後続の処理を制御する場合は、ご注意ください。

運用バッチ(DailySch.bat)作成例

@ECHO OFF
SETLOCAL

rem ***********************************************************
rem * 設定                                                    *
rem ***********************************************************
rem 出力先のドライブ名を記述
SET BKDRIVE=D:

rem 出力先のフォルダ名を記述
SET BKFOLDERNAME=\BACKUP

rem 処理終了日を設定するための、計測日数を記述
SET DELEND=90

rem データベースへの接続ユーザーIDを記述
SET SQLUSER=dtkbkuser

rem データベースへの接続パスワードを記述
SET SQLPASSWORD=dtkpsw

rem バックアップコマンド格納先を記述
SET BACKUPCOMMANDFOLDER=C:\DTK\BackupCommand

rem 抽出キー(省略時はクライアント日時、SERVERはサーバ日時)
SET HOW=SERVER

rem ***************************************************************
rem * 処理部                                                      *
rem ***************************************************************
path %BACKUPCOMMANDFOLDER%;%path%
echo バックアップ処理起動(%TIME%)

%BKDRIVE%
CD %BKFOLDERNAME%

rem バックアップ終了日の計算
%BACKUPCOMMANDFOLDER%\DTKBFDM.EXE %DELEND%

rem 実行日でディレクトリを作成
SET TEMPDATE=%ERRORLEVEL%
MKDIR %TEMPDATE%

rem バックアップ先ディレクトリを作成
SET MSFOLDER=%BKDRIVE%%BKFOLDERNAME%\%TEMPDATE%\MS%TEMPDATE%
MKDIR %MSFOLDER%

echo DTKサービス(階層化サービス)を停止します。
net stop SWLevelControlService
if ERRORLEVEL 1 goto recover1
echo DTKサービス(サーバサービス)を停止します。
net stop SWServerService
if ERRORLEVEL 1 goto recover2

rem マスタ系データのバックアップ
%BACKUPCOMMANDFOLDER%\DTKMSTB.EXE DTKDB %SQLUSER% %SQLPASSWORD% %MSFOLDER%

if ERRORLEVEL 1 goto recover3

rem ログ系データのバックアップと削除
CALL %BACKUPCOMMANDFOLDER%\DTKCVDL
if ERRORLEVEL 1 goto recover4

echo DTKサービスを起動します。
net start SWLevelControlService
net start SWServerService
echo スケジュールが正常終了しました。(%TIME%)
EXIT /B 0

:recover1
echo 階層化サービス停止がエラーになりました。
echo バックアップは取りやめ、DTKサービス(階層化サービス)を起動します。
goto allend1

:recover2
echo サーバサービス停止がエラーになりました。
echo バックアップは取りやめ、DTKサービス(階層化サービス、サーバサービス)を起動します。
goto allend1

:recover3
echo 管理情報のバックアップがエラーになりました。
echo バックアップは取りやめ、DTKサービス(階層化サービス、サーバサービス)を起動します。
goto allend1

:recover4
echo ログのバックアップと削除がエラーになりました。
echo ログのバックアップ・削除は取りやめ、DTKサービス(階層化サービス、サーバサービス)を起動します。
goto allend1

:allend1
echo DTKサービスを起動します。
net start SWLevelControlService
net start SWServerService
echo スケジュールが異常終了しました。(%TIME%)
EXIT /B 1

登録バッチ(XXXXX.bat)作成例

@ECHO OFF
SETLOCAL

rem ***********************************************************
rem * 設定                                                    *
rem ***********************************************************
set BACKUPCOMMANDFOLDER=C:\DTK\BackupCommand

rem ***********************************************************
rem * 処理部                                                  *
rem ***********************************************************
rem 実行日の計算
%BACKUPCOMMANDFOLDER%\DTKBFDM.EXE 0
SET EXECDAY=%ERRORLEVEL%

call DailySch.bat > %EXECDAY%.log
if ERRORLEVEL 1 goto allend1

EXIT /B 0

:allend1
EXIT /B 1

バッチファイルの実行結果ログの例

実行結果ログとは、上記登録バッチ例のDailySch.batの実行結果出力ログ(%EXECDAY%.log)です。

バックアップ処理起動(12:50:27.87)
DTKサービス(階層化サービス)を停止します。
SWLevelControlService サービスを停止中です.
SWLevelControlService サービスは正常に停止されました。

DTKサービス(サーバサービス)を停止します。
SWServerService サービスを停止中です
SWServerService サービスは正常に停止されました。

2009/06/08 12:50:33  管理情報を一括でバックアップ・開始
2009/06/08 12:50:33  
2009/06/08 12:50:33    データベース      ：  DTKDB
2009/06/08 12:50:33    ディレクトリ      ：  D:\BACKUP\20090310\MS20090310
2009/06/08 12:50:33  
2009/06/08 12:50:33    ○  LEVELOBJECT
2009/06/08 12:50:33        出力ファイル名  ：  D:\BACKUP\20090310\MS20090310\LEVELOBJECT.csv
2009/06/08 12:50:33        出力件数・・・・・1件
2009/06/08 12:50:33  
2009/06/08 12:50:33    ○  LEVELCOMPOSITION
2009/06/08 12:50:33        出力ファイル名  ：  D:\BACKUP\20090310\MS20090310\LEVELCOMPOSITION.csv
2009/06/08 12:50:33        出力件数・・・・・0件
2009/06/08 12:50:33  

    ～～（略）～～

2009/06/08 12:50:42    ○  FILEBRINGOUTLOG
2009/06/08 12:50:42        2009/02/01を処理  ・・・  84件削除
2009/06/08 12:50:42        削除件数・・・・・84件
2009/06/08 12:50:42  
2009/06/08 12:50:42    ○  LOGKEYWORDS
2009/06/08 12:50:42        2009/02/01を処理  ・・・  438件削除
2009/06/08 12:50:44        削除件数・・・・・438件
2009/06/08 12:50:44  
2009/06/08 12:50:44    ○  FILEACCESSLOG
2009/06/08 12:50:44        2009/02/01を処理  ・・・  446件削除
2009/06/08 12:50:45        削除件数・・・・・446件
2009/06/08 12:50:45  
2009/06/08 12:50:45  ログ情報を削除・終了
DTKサービスを起動します。
SWLevelControlService サービスを開始します.
SWLevelControlService サービスは正常に開始されました。

SWServerService サービスを開始します..
SWServerService サービスは正常に開始されました。

スケジュールが正常終了しました。(12:50:51.89)

事例－II：91日以前のログを削除し、直近1週間のログをバックアップする場合（ログ保存期間：3カ月）

運用条件

  • 運用として、データの保存期間を90日とし、それ以前のデータはデータベース上に残さず、ファイルへデータをバックアップします。

  • 毎日、直近１週間のデータを、指定したドライブにバックアップ開始日の日付が付いたディレクトリ名を作成し、その下にデータをバックアップした出力ファイルを置きます。

  • バックアップ対象は、以下のとおりです。

    • 管理情報に記述されているすべてのテーブル(DTKMSTBを利用)

    • ログ情報（DB上のログデータおよびコマンドプロンプト操作ログ)に記述されているすべてのテーブル、およびデータベースに蓄積されているログの情報

    退避可能な情報の詳細については、“3.1.1.2 ユーザー資産”を参照してください。

  • 91日以前のデータ部分はデータベースより削除します。

  • バックアップの実行は、OS標準実装の「タスク」機能を使用し自動起動します。ただし、データベースのレコード削除も行うため、Systemwalker Desktop Keeperのサーバ側の処理との間でデータベースアクセスの競合を発生させないように、Systemwalker Desktop Keeperのサーバ側サービスを停止してから行います。

  • サーバ側サービスを停止させることから、利用者の少ない夜間の2時より起動することとします。

  • バックアップおよびデータベースのレコード削除にかかる時間は事前に検証を行い、合わせて30分程度で終了する想定としています。


以下のような運用を想定しています。

例では、退避期間を退避実行日付から1週間前までを退避、91日以前を削除する運用とします。


運用設定

上記の“運用条件”で説明した運用を行うために、提供するバックアップコマンドの中から、DTKMSTB、DTKLGTB、DTKLG1T、DTKDELRを使用します。

なお、本運用設定により、バックアップ先のドライブおよびフォルダの構成は、以下のようになります。(XXXXXXXXはバックアップ開始日になります)

  • 管理情報に記述されているすべてのテーブル

    →D:\BACKUP\XXXXXXXX\MSXXXXXXXX\ 配下

  • ログ情報（DB上のログデータおよびコマンドプロンプト操作ログ) に記述されているすべてのテーブル

    →D:\BACKUP\XXXXXXXX\BKXXXXXXXX\ 配下

  • データベースに蓄積されているログの情報

    →D:\BACKUP\XXXXXXXX\LVXXXXXXXX\ 配下

退避可能な情報の詳細については、“3.1.1.2 ユーザー資産”を参照してください。

運用設定の手順は、以下のとおりです。

  1. 「タスク」より起動するバッチファイルをテキストエディタで作成します。
    なお、バッチファイルは、後述する“スケジュール登録するバッチファイルの作成例”のように記述します。

  2. 作成したバッチファイルを「C:\DTK\BackupCommand」に「DailySch.bat」として保存します。

  3. 運用設定で決定したログ保存先フォルダを作成します。
    運用例では、D:\BACKUPです。

  4. 「タスク」に「XXXXX.bat」のコマンドを登録します。

    1. [スタート]-[設定]-[コントロールパネル]-[タスク]と開き、スケジュールされたタスクの追加をダブルクリックします。

    2. タスクウィザードで、実行するプログラムの選択画面にて、[参照]ボタンを押下して「C:\DTK\BackupCommand\XXXXX.bat」を登録します。

    3. 名前を付け、日単位の実行として、毎日2:00に実行として登録します。

    4. 実行時のユーザーIDとパスワードを登録するので、Administrator権限のあるユーザーで登録します。


バッチファイルの作成例

運用バッチとタスクに登録する登録バッチの作成例を以下に示します。

なお、このバッチコマンド作成例では、バッチ内で呼び出したNetコマンドの復帰値をバッチコマンドの復帰値とはしないようになっています。Netコマンドの復帰値を利用して、後続の処理を制御する場合は、ご注意ください。

運用バッチ(DailySch.bat)作成例

@ECHO OFF
SETLOCAL

echo 設定開始
rem *************************************************************
rem * 設定                                                      *
rem *************************************************************
rem 出力先のドライブ名を記述
SET BKDRIVE=D:

rem 出力先のフォルダ名を記述
SET BKFOLDERNAME=\BACKUP

rem バックアップを何日前から開始するかを記述
rem 例 7日前を指定する場合
SET BKSTART=7

rem データの削除を何日より前まで行うかを記述
rem 例 90日より前を指定する場合
SET DELEND=90

rem データベースへの接続ユーザーIDを記述
SET SQLUSER=dtkbkuser

rem データベースへの接続パスワードを記述
SET SQLPASSWORD=dtkpsw

rem バックアップコマンド格納先を記述
SET BACKUPCOMMANDFOLDER=C:\DTK\BackupCommand

rem 抽出キー(省略時はクライアント日時、SERVERはサーバ日時)
SET HOW=SERVER

rem ***************************************************************
rem * 処理部                                                      *
rem ***************************************************************
path %BACKUPCOMMANDFOLDER%;%path%
echo バックアップ処理起動(%TIME%)

%BKDRIVE%
CD %BKFOLDERNAME%

echo バックアップ開始日計算
rem バックアップ開始日の計算
%BACKUPCOMMANDFOLDER%\DTKBFDM.EXE %BKSTART%
SET BKSTARTDAY=%ERRORLEVEL%

rem バックアップ終了日の計算
%BACKUPCOMMANDFOLDER%\DTKBFDM.EXE 0
SET BKENDDAY=%ERRORLEVEL%

rem 削除終了日の計算
%BACKUPCOMMANDFOLDER%\DTKBFDM.EXE %DELEND%
SET DELENDDAY=%ERRORLEVEL%

rem バックアップ開始日でフォルダ作成(ログデータ)
MKDIR %BKSTARTDAY%
SET BKFOLDER=%BKDRIVE%%BKFOLDERNAME%\%BKSTARTDAY%\BK%BKSTARTDAY%
MKDIR %BKFOLDER%

rem バックアップ開始日でフォルダ作成(参照データ)
SET LVFOLDER=%BKDRIVE%%BKFOLDERNAME%\%BKSTARTDAY%\LV%BKSTARTDAY%
MKDIR %LVFOLDER%

rem バックアップ先ディレクトリを作成
SET MSFOLDER=%BKDRIVE%%BKFOLDERNAME%\%BKSTARTDAY%\MS%BKSTARTDAY%
MKDIR %MSFOLDER%

echo DTKサービス(階層化サービス)を停止します。
net stop SWLevelControlService
if ERRORLEVEL 1 goto recover1
echo DTKサービス(サーバサービス)を停止します。
net stop SWServerService
if ERRORLEVEL 1 goto recover2

rem マスタ系データのバックアップ
%BACKUPCOMMANDFOLDER%\DTKMSTB.EXE DTKDB %SQLUSER% %SQLPASSWORD% %MSFOLDER%

if ERRORLEVEL 1 goto recover3

rem ログ系データのバックアップ
%BACKUPCOMMANDFOLDER%\DTKLGTB.exe DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% %BKFOLDER% %HOW%

if ERRORLEVEL 1 goto recover4

rem ログ系(参照)のバックアップ
%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 3 %LVFOLDER%\アプリケーション起動禁止ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 9 %LVFOLDER%\印刷禁止ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 10 %LVFOLDER%\ログオン禁止ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 12 %LVFOLDER%\PrintScreenキー禁止ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 1 %LVFOLDER%\アプリケーション起動ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 2 %LVFOLDER%\アプリケーション終了ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 4 %LVFOLDER%\ウィンドウタイトル取得ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 17 %LVFOLDER%\ウィンドウタイトル取得(URL付き)ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 5 %LVFOLDER%\メール送信ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 7 %LVFOLDER%\デバイス構成変更ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 8 %LVFOLDER%\印刷操作ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 11 %LVFOLDER%\ファイル持出しログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 6 %LVFOLDER%\コマンドプロンプトログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 13 %LVFOLDER%\ファイル操作ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 16 %LVFOLDER%\メール添付禁止ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 90 %LVFOLDER%\連携アプリケーションログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 14 %LVFOLDER%\ログオン・ログオフログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 24 %LVFOLDER%\FTP操作禁止ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 25 %LVFOLDER%\FTP操作ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 29 %LVFOLDER%\Web操作禁止ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 31 %LVFOLDER%\Web操作ログ.csv %how%
if ERRORLEVEL 1 goto recover5

%BACKUPCOMMANDFOLDER%\DTKLG1T.EXE DTKDB %SQLUSER% %SQLPASSWORD% %BKSTARTDAY% %BKENDDAY% 34 %LVFOLDER%\メール送信中止ログ.csv %how%
if ERRORLEVEL 1 goto recover5

rem ログ系データの削除
C:\DTK\BackupCommand\DTKDELR.exe DTKDB %SQLUSER% %SQLPASSWORD% 00000000 %DELENDDAY% -Y %HOW%
if ERRORLEVEL 100 goto allend0
goto recover6

:recover1
echo 階層化サービス停止がエラーになりました。
echo バックアップは取りやめ、DTKサービス(階層化サービス)を起動します。
goto allend1

:recover2
echo サーバサービス停止がエラーになりました。
echo バックアップは取りやめ、DTKサービス(階層化サービス、サーバサービス)を起動します。
goto allend1

:recover3
echo 管理情報のバックアップがエラーになりました。
echo バックアップは取りやめ、DTKサービス(階層化サービス、サーバサービス)を起動します。
goto allend1

:recover4
echo ログ情報のバックアップがエラーになりました。
echo バックアップは取りやめ、DTKサービス(階層化サービス、サーバサービス)を起動します。
goto allend1

:recover5
echo ログ情報(参照)のバックアップがエラーになりました。
echo バックアップは取りやめ、DTKサービス(階層化サービス、サーバサービス)を起動します。
goto allend1

:recover6
echo ログ情報の削除がエラーになりました。
echo ログ情報の削除は取りやめ、DTKサービス(階層化サービス、サーバサービス)を起動します。
goto allend1

:allend0
echo DTKサービスを起動します。
net start SWLevelControlService
net start SWServerService
echo スケジュールが正常終了しました。(%TIME%)
EXIT /B 0

:allend1
echo DTKサービスを起動します。
net start SWLevelControlService
net start SWServerService
echo スケジュールが異常終了しました。(%TIME%)
EXIT /B

登録バッチ(XXXXX.bat)作成例

@ECHO OFF
SETLOCAL

rem ***********************************************************
rem * 設定                                                    *
rem ***********************************************************
set BACKUPCOMMANDFOLDER=C:\DTK\BackupCommand

rem ***********************************************************
rem * 処理部                                                  *
rem ***********************************************************
rem 実行日の計算
%BACKUPCOMMANDFOLDER%\DTKBFDM.EXE 0
SET EXECDAY=%ERRORLEVEL%

call DailySch.bat > %EXECDAY%.log
if ERRORLEVEL 1 goto allend1

EXIT /B 0

:allend1
EXIT /B 1

バッチファイルの実行結果ログの例

実行結果ログとは、上記登録バッチ例のDailySch.batの実行結果出力ログ(%EXECDAY%.log)です。

設定開始
バックアップ処理起動(13:52:01.43)
バックアップ開始日計算
DTKサービス(階層化サービス)を停止します。
SWLevelControlService サービスを停止中です.
SWLevelControlService サービスは正常に停止されました。

DTKサービス(サーバサービス)を停止します。
SWServerService サービスを停止中です.
SWServerService サービスは正常に停止されました。

2009/06/08 13:52:06  管理情報を一括でバックアップ・開始
2009/06/08 13:52:06  
2009/06/08 13:52:06    データベース      ：  DTKDB
2009/06/08 13:52:06    ディレクトリ      ：  D:\BACKUP\20090601\MS20090601
2009/06/08 13:52:06  
2009/06/08 13:52:07    ○  LEVELOBJECT
2009/06/08 13:52:07        出力ファイル名  ：  D:\BACKUP\20090601\MS20090601\LEVELOBJECT.csv
2009/06/08 13:52:07        出力件数・・・・・2件
2009/06/08 13:52:07  
2009/06/08 13:52:07    ○  LEVELCOMPOSITION
2009/06/08 13:52:07        出力ファイル名  ：  D:\BACKUP\20090601\MS20090601\LEVELCOMPOSITION.csv
2009/06/08 13:52:07        出力件数・・・・・1件
2009/06/08 13:52:07  

    ～～（略）～～

2009/06/08 13:52:16    ○  LOGKEYWORDS
2009/06/08 13:52:16        2009/02/01を処理  ・・・  223件削除
2009/06/08 13:52:17        削除件数・・・・・223件
2009/06/08 13:52:17  
2009/06/08 13:52:17    ○  FILEACCESSLOG
2009/06/08 13:52:17        2009/02/01を処理  ・・・  446件削除
2009/06/08 13:52:18        削除件数・・・・・446件
2009/06/08 13:52:18  
2009/06/08 13:52:18  ログ情報を削除・終了
DTKサービスを起動します。
SWLevelControlService サービスを開始します
SWLevelControlService サービスは正常に開始されました。

SWServerService サービスを開始します..
SWServerService サービスは正常に開始されました。

スケジュールが正常終了しました。(13:52:24.92)

前次
Copyright 2005 - 2011 FUJITSU LIMITED