C.3.3 BLOB型データの参照

BLOB型データを参照するサンプルコードについて説明します。

本サンプルコードは、GetChunkメソッドで16384バイトずつBLOB型データを取得します。取得したBLOB型データはOpenステートメントを使用してファイルに出力します。出力したデータをピクチャボックスコントロールで表示します。事前にフォームへピクチャボックスコントロール(PictureBox1)を追加してください。

アプリケーションの手順

コネクションを接続します。詳細は、“C.3.1 接続および切断”を参照してください。
Recordsetオブジェクトを生成します。
Recordset.OpenメソッドでRecordsetオブジェクトを開きます。
Recordsetオブジェクトよりデータを取得します。
Recordset.EOFプロパティでカレント行がEOFかを確認します。
Field.ActualSizeプロパティで取得データのバイト数を確認します。
Field.GetChunkメソッドで指定バイト数分データを取得します。
Recordset.MoveNextメソッドでカレント行を次の行へと移動します。
Recordset.CloseメソッドでRecordsetオブジェクトを閉じます。
コネクションを切断します。
オブジェクトを破棄します。

エラー処理については、“C.3.11 エラー処理”を参照してください。

'オブジェクト宣言
Dim Con As Connection
Dim Rst As Recordset

Dim DataFile As Integer
Dim Chunks As Integer
Dim Fl As Long
Dim Fragment As Integer
Dim Chunk() As Byte
Const ChunkSize As Integer = 16384
Dim k As Integer
Dim i As Integer


'Connectionオブジェクトの生成と設定
Set Con = New Connection
Con.ConnectionString = "DSN=DSN01;UID=USER01;PWD=PASS01;"

On Error GoTo ErrorProc

'1. コネクション接続
Con.Open

'2. Recordsetオブジェクトの生成
Set Rst = New Recordset

'3. Recordsetオブジェクトを開く
Rst.Open "SELECT * FROM IMGTBL", Con, _
         adOpenForwardOnly, _
         adLockReadOnly, _
         adCmdText

'行カウントの初期化
i = 1

'4. データの取得
'EOFまで繰り返し
Do Until Rst.EOF

    'BLOB型データのサイズを取得
    Fl = Rst.Fields("BLB_C").ActualSize

    'BLB_C列にデータがあるか
    If Fl > 0 Then
        'BLOB型データが存在する場合

        '表示しているイメージを消す
        Picture1.Picture = Nothing

        '規定量にデータを分けて取得するため、分割数と残量を求める
        Chunks = Fl \ ChunkSize
        Fragment = Fl Mod ChunkSize

        '残量分のデータ取得
        ReDim Chunk(Fragment - 1)
        Chunk = Rst.Fields("BLB_C").GetChunk(Fragment)

        'FileStreamオブジェクトの生成(ファイルを開く)
        DataFile = FreeFile
        Open "pictemp" For Binary Access Write As DataFile

        'BLOB型データをファイルに出力する
        Put DataFile, , Chunk()

        ReDim Chunk(ChunkSize - 1)
        '分割数分繰り返し
        For k = 1 To Chunks
            '規定量分のデータ取得
            Chunk = Rst.Fields("BLB_C").GetChunk(ChunkSize)
            'BLOB型データをファイルに出力する
            Put DataFile, , Chunk()
        Next k

        'FileStreamオブジェクトを閉じる
        Close DataFile

        '出力したファイルをPictureBoxコントロールで表示する
        Picture1.AutoSize = True
        Picture1.Picture = LoadPicture("pictemp")
        Kill "pictemp"

    End If
    'メッセージボックスの表示
    MsgBox i & "行目を取得しました", _
                    vbOKOnly, "Message"
    '行の位置づけ
    Rst.MoveNext
    i = i + 1
Loop

'5. Recordsetオブジェクトを閉じる
Rst.Close

'6. コネクション切断
Con.Close

'7. オブジェクトの破棄
Set Rst = Nothing
Set Con = Nothing

'表示しているイメージを消す
Picture1.Picture = Nothing

Exit Sub

'エラー処理
ErrorProc:

'エラー処理ルーチンを記述します