Interstage Shunsaku Data Manager アプリケーション開発ガイド

H.1.4 検索条件に一致するXML文書をソートして取得する

検索操作において、検索した結果をある特定の要素をキーとしてソートして取得したい場合があります。

日付と場所を検索条件式に指定して、条件に一致するホテルの件数と部分情報を取得します。

データを取得する際に、宿泊費の高い順に取り出す例を用いて、VB .NETの使用例を示します。

検索条件

「2006年7月18日に大阪で宿泊可能なホテルを、宿泊費の高い順に並べて取得したい。」

年月日(2006年7月18日)および、場所(大阪)を条件に指定します。また、ソート条件に宿泊費を指定し、検索を実行します。

APIの使用例

以下にVB .NETを使用したプログラミング例を示します。

Imports System
Imports Fujitsu.Shunsaku
Imports System.ComponentModel

Class SampleSort1

  Shared Public Function Main( ByVal args() As String ) As Integer
    Dim service As ShunService = Nothing

    Try
      '' ShunService の作成
      service = new ShunService()

      '' ホスト名 ポート番号を指定して Shunsaku に接続
      service.Host = "DirSrv1"
      service.Port = 23101
      service.Connect()

      '' ShunSearchRequirement の作成
      Dim req As ShunSearchRequirement = new ShunSearchRequirement()
      
      '' 各種検索条件の設定
      req.QueryExpression = "/document {/base/prefecture == '大阪' AND /information/date == '2006年07月18日'}"
      req.ReturnExpression = "/document/base/name, /document/base/price"
      req.SortExpression = "/document/base/price/text() DESC"
      req.ReplyNumber = 1
      req.RequestCount = 30
      
      '' 検索条件を指定して検索を実行
      Dim rs As ShunResultSet = service.Search( req )

      '' 検索結果の表示
      Console.WriteLine( "ヒット件数  = {0}", rs.HitCount )
      Dim i As Integer = 0
      For Each record As ShunRecord In rs.Records
        i += 1
        Console.WriteLine( "[結果]{0}件目 = {1}", i, record.Data )
      Next

      '' Shunsaku から切断
      service.Disconnect()
    
    Catch e As ShunContinuousException
      '' ShunContinuousExceptionが発生した場合の処理を記述
      Try
        If Not service Is Nothing And service.State = ShunConnectionState.Open Then
          service.Disconnect()
        End If
      Catch ex As ShunException
        Console.WriteLine( "エラーメッセージ : {0}", ex.Message )
      End Try
      Console.WriteLine( "エラーメッセージ : {0}", e.Message )
    
    Catch e As ShunConnectionTerminatedException
      '' ShunConnectionTerminatedExceptionが発生した場合の処理を記述
      Console.WriteLine( "エラーメッセージ : {0}", e.Message )

    End Try
  End Function
End Class

実行結果

Number of hits = 3
[結果]1件目 = <document><name>ホテル１</name><price>9000</price></document>
[結果]2件目 = <document><name>ホテル３</name><price>7500</price></document>
[結果]3件目 = <document><name>ホテル２</name><price>6000</price></document>